# .text.init セクションは、
  # https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/test.ld#L25-L26
  # にて 0x80000000 番地に置かれている。
  .section ".text.init"
  .globl _start
_start:
  # 各種レジスタをゼロクリア
  li  x1, 0
  li  x2, 0
  li  x3, 0
  li  x4, 0
  li  x5, 0
  li  x6, 0
  li  x7, 0
  li  x8, 0
  li  x9, 0
  li  x10,0
  li  x11,0
  li  x12,0
  li  x13,0
  li  x14,0
  li  x15,0
  li  x16,0
  li  x17,0
  li  x18,0
  li  x19,0
  li  x20,0
  li  x21,0
  li  x22,0
  li  x23,0
  li  x24,0
  li  x25,0
  li  x26,0
  li  x27,0
  li  x28,0
  li  x29,0
  li  x30,0
  li  x31,0

  # enable FPU and accelerator if present
  li t0, MSTATUS_FS | MSTATUS_XS
  csrs mstatus, t0

  # make sure XLEN agrees with compilation choice
  li t0, 1
  slli t0, t0, 31
#if __riscv_xlen == 64
  # RV64ターゲットでコンパイルした場合はこちらに入る。
  # もしも t0 が32ビットレジスタ（つまりプロセッサはRV32）なのに、現在実行しているコンパイル済みの実行可能ファイルが
  # __riscv_xlen == 64 としてコンパイルされており、このコードパスに入っているとする。
  # その場合は、 t0 = 1 << 31 == 10000000 00000000 00000000 00000000 であり、これは符号付き32ビット整数と解釈すると -2147483648 である。
  # したがって t0 < 0 なので、直下の bgez は不成立となり、 2: が実行される。
  bgez t0, 1f  # 1f は "forward方向の 1: ラベル" を指す。
#else
  bltz t0, 1f
#endif
2:
  # ここに入ると無限ループ。
  # sw で何をしているのかは理解できていない...
  li a0, 1
  sw a0, tohost, t0
  j 2b  # 2b は "backward方向の 2: ラベル" を指す。
1:

#ifdef __riscv_flen
  # initialize FPU if we have one
  # 例外が発生した場合のジャンプ先を、この数行後の 1: ラベルの番地とする。
  # 1: ラベル直後においても再び例外発生の際のジャンプ先を設定しているが、これは、プロセッサが実際には浮動小数点演算をサポートしていない場合には、
  # 1: ラベルに至る前の fssr や fmv.s.x 命令が例外を発生させてしまう可能性があるからだと思われる。
  #
  # mtvec の値の仕様は https://content.riscv.org/wp-content/uploads/2017/05/riscv-privileged-v1.10.pdf を参照。
  la t0, 1f
  csrw mtvec, t0 

  # 浮動小数点のコントロールレジスタ fcsr を0にセット。
  # fssr 命令は古く、 fscsr 命令に成り代わった模様: https://github.com/riscv/riscv-isa-manual/issues/419#issuecomment-516338426
  fssr    x0
  # 浮動小数点数演算のための汎用レジスタをゼロクリア。
  fmv.s.x f0, x0
  fmv.s.x f1, x0
  fmv.s.x f2, x0
  fmv.s.x f3, x0
  fmv.s.x f4, x0
  fmv.s.x f5, x0
  fmv.s.x f6, x0
  fmv.s.x f7, x0
  fmv.s.x f8, x0
  fmv.s.x f9, x0
  fmv.s.x f10,x0
  fmv.s.x f11,x0
  fmv.s.x f12,x0
  fmv.s.x f13,x0
  fmv.s.x f14,x0
  fmv.s.x f15,x0
  fmv.s.x f16,x0
  fmv.s.x f17,x0
  fmv.s.x f18,x0
  fmv.s.x f19,x0
  fmv.s.x f20,x0
  fmv.s.x f21,x0
  fmv.s.x f22,x0
  fmv.s.x f23,x0
  fmv.s.x f24,x0
  fmv.s.x f25,x0
  fmv.s.x f26,x0
  fmv.s.x f27,x0
  fmv.s.x f28,x0
  fmv.s.x f29,x0
  fmv.s.x f30,x0
  fmv.s.x f31,x0
1:
#endif

  # initialize trap vector
  la t0, trap_entry
  csrw mtvec, t0

  # initialize global pointer
  # グローバル変数のアドレスは gp をベースにして計算する。
  # .option push / .option pop は、それらに挟まれたオプション設定を一時的に有効にするためのGNU Assemblerのオプション。
  # .option norelax はリンカによるrelaxを明示的に拒否するためのオプション。
  # https://www.st.com/content/ccc/resource/technical/document/user_manual/group1/fb/cb/d6/71/03/25/42/a1/UserManual_GNU_Assembler/files/UserManual_GNU_Assembler.pdf/jcr:content/translations/en.UserManual_GNU_Assembler.pdf
  # の p.257-258 に詳しい。
.option push
.option norelax
  la gp, __global_pointer$
.option pop

  # tp: thread pointer
  # スレッドローカル変数のアドレスは tp をベースにして計算する。
  # _end は https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/test.ld#L63 の番地。
  # ただし、 riscv-tests/benchmarks においては、
  # https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/test.ld#L53
  # で引っ張ってきている .tdata セクションは指定されていない。つまりスレッドローカル変数は使われていない。
  la  tp, _end + 63
  and tp, tp, -64

  # get core id
  csrr a0, mhartid
  # for now, assume only 1 core
  li a1, 1
# mhartid (物理スレッドID, CPUコアID) が1以上ならば、この bgeu を無限ループ（スピンウェイト）する。
# つまりコア番号0のCPUコアでしか以降の命令（ベンチマーク）は実行されないようになっている。
# ベンチマークプログラムとしてはマルチスレッド対応がほしいところなので、これが緩和されるようIssueが立っている（立てた）。
# https://github.com/riscv/riscv-tests/issues/240
1:bgeu a0, a1, 1b

  # give each core 128KB of stack + TLS
  #
  # ここでは、 mhartid が 0, 1, 2, 3 な4コアの環境で、スタック領域とスレッドローカル変数の割当を図示する。
  # （上述の通り mhartid == 0 しかこのコードは通らないが、もしその制約が撤廃されたらの話）
  #
  # ----------- sp (core#3)
  #  ^
  #  | 2^17
  #  |
  #  v
  # ----------- sp (core#2) = tp (core#3)
  #  ^
  #  | 2^17
  #  |
  #  v
  # ----------- sp (core#1) = tp (core#2)
  #  ^
  #  | 2^17
  #  |
  #  v
  # ----------- sp (core#0) = tp (core#1)
  #  ^
  #  | 2^17
  #  |
  #  v
  # ----------- tp (core#0) = (_end + 63) & -64
  #
  # 各コア、スタックポインタは下方向に（低位に向かって）伸ばし、スレッドポインタは上方向に（高位に向かって）伸ばす。
  #
#define STKSHIFT 17
  add sp, a0, 1
  sll sp, sp, STKSHIFT
  add sp, sp, tp
  sll a2, a0, STKSHIFT
  add tp, tp, a2

  # _init 関数へジャンプ。
  #   a0 = mhartid (CPUコアのID) ; ただし mhartid != 0 はこのコードパスに到達しない。
  #   a1 = 1 (コア数)
  # の2引数を _init に渡す。
  j _init

# この後は、例外発生時のジャンプ先の例外ハンドラが続く（省略）
  .align 2
trap_entry:
...

void _init(int cid, int nc)  // cid = CPUコアID, nc = 1
{
  init_tls();
  thread_entry(cid, nc);

  // only single-threaded programs should ever get here.
  int ret = main(0, 0);

  char buf[NUM_COUNTERS * 32] __attribute__((aligned(64)));
  char* pbuf = buf;
  for (int i = 0; i < NUM_COUNTERS; i++)
    if (counters[i])
      pbuf += sprintf(pbuf, "%s = %d\n", counter_names[i], counters[i]);
  if (pbuf != buf)
    printstr(buf);

  exit(ret);
}

static void init_tls()
{
  // 各CPUコアの tp (thread pointer) の値を thread_pointer 変数に格納。
  register void* thread_pointer asm("tp");
  
  // リンカスクリプトの
  // https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/test.ld#L49-L60
  // で確保しているTLSの境界値をここで使えるように宣言。
  extern char _tdata_begin, _tdata_end, _tbss_end;

  // _tdata_begin から始まる tdata_size 分の領域を、自分のCPUコアの tp の箇所にコピーする（TLSは上（高位）に向かって伸びる）。
  // つまり、各CPUコアは予め同じ _tdata_begin のデータをTLSに持った状態でプログラムが開始する。
  size_t tdata_size = &_tdata_end - &_tdata_begin;
  // memcpy の実装は、シンプルにポインタを1バイトずつ操作するものが定義されている。
  // https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/syscalls.c#L379-L393
  memcpy(thread_pointer, &_tdata_begin, tdata_size);

  // BSSセクションはゼロ初期化するものなので、 _tdata を配置したその上に、 tbss_size 分だけゼロクリアする。
  size_t tbss_size = &_tbss_end - &_tdata_end;
  // memset はこちら https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/syscalls.c#L395-L412
  memset(thread_pointer + tdata_size, 0, tbss_size);
}

// GNU拡張を使って weak シンボルとして thread_entry のデフォルト定義が与えられている。
// 静的・動的リンク時に別の thread_entry シンボルが見つかったらそちらが優先的に使われる。
void __attribute__((weak)) thread_entry(int cid, int nc)
{
  // multi-threaded programs override this function.
  // for the case of single-threaded programs, only let core 0 proceed.
  // コアID0 以外はここでずっと足止めを食らう。
  / crt.S でもコアID0 以外が無限ループを食らう箇所があったが、あの制約が撤廃されても、
  // thread_entry 関数を自前で書かないベンチマークアプリケーションはシングルスレッド処理になる。
  while (cid != 0);
}

void _init(int cid, int nc)  // cid = CPUコアID, nc = 1
{
  init_tls();
  thread_entry(cid, nc);

  // only single-threaded programs should ever get here.
  int ret = main(0, 0);

  // パフォーマンスカウンタの内容をコンソール出力する、シングルスレッドベンチマークの共通後処理。
  // buf はコンソール出力する文字列を格納する領域。サイズはパフォーマンスカウンタの個数 * 32。
  // 1個のカウンタあたり最長32バイトの文字出力ができるようにしている。
  // NUM_COUNTERS は
  // https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/syscalls.c#L36-L38
  // で2個に固定されている。Spikeでの実行例で見たように、 mcycle, minstret の2つに設定されている。
  // 設定箇所をするための関数は
  // https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/syscalls.c#L39-L54
  // であり、各アプリケーションから計測対象コードの前後で setStats(1); setStats(0) されている。
  char buf[NUM_COUNTERS * 32] __attribute__((aligned(64)));
  char* pbuf = buf;
  for (int i = 0; i < NUM_COUNTERS; i++)
    if (counters[i])
      pbuf += sprintf(pbuf, "%s = %d\n", counter_names[i], counters[i]);
  if (pbuf != buf)
    printstr(buf);
  // sprintf や printstr はSpikeの用意しているシステムコール呼び出しを使って実現している。

  // exit() の処理は、コードを追っていくと最終的に
  // https://github.com/riscv/riscv-tests/blob/3a98ec2e306938cce07ab15e3678d670611aa66d/benchmarks/common/syscalls.c#L56-L60
  // の tohost_exit() に行き着く。
  exit(ret);
}

void __attribute__((noreturn)) tohost_exit(uintptr_t code)
{
  tohost = (code << 1) | 1;  // tohost という変数に main 関数の返り値を左シフトして最下位ビットを1にした値を書き込み
  while (1);                 // 無限ループ
}

void vvadd( int n, int a[], int b[], int c[] )
{
  int i;
  for ( i = 0; i < n; i++ )
    c[i] = a[i] + b[i];
}

int main( int argc, char* argv[] )
{
  int results_data[DATA_SIZE];

#if PREALLOCATE
  // If needed we preallocate everything in the caches
  vvadd( DATA_SIZE, input1_data, input2_data, results_data );
#endif

  // Do the vvadd
  setStats(1);  // パフォーマンスカウンタ mcycle, minstret の値を記録
  vvadd( DATA_SIZE, input1_data, input2_data, results_data );
  setStats(0);  // パフォーマンスカウンタ mcycle, minstret の増分を記録。main() 終了後に増分がコンソール出力される。

  // Check the results
  return verify( DATA_SIZE, results_data, verify_data );
}